!!$ 
!!$              Parallel Sparse BLAS  v2.0
!!$    (C) Copyright 2006 Salvatore Filippone    University of Rome Tor Vergata
!!$                       Alfredo Buttari        University of Rome Tor Vergata
!!$ 
!!$  Redistribution and use in source and binary forms, with or without
!!$  modification, are permitted provided that the following conditions
!!$  are met:
!!$    1. Redistributions of source code must retain the above copyright
!!$       notice, this list of conditions and the following disclaimer.
!!$    2. Redistributions in binary form must reproduce the above copyright
!!$       notice, this list of conditions, and the following disclaimer in the
!!$       documentation and/or other materials provided with the distribution.
!!$    3. The name of the PSBLAS group or the names of its contributors may
!!$       not be used to endorse or promote products derived from this
!!$       software without specific written permission.
!!$ 
!!$  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
!!$  ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
!!$  TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
!!$  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE PSBLAS GROUP OR ITS CONTRIBUTORS
!!$  BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
!!$  CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
!!$  SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
!!$  INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
!!$  CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
!!$  ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
!!$  POSSIBILITY OF SUCH DAMAGE.
!!$ 
!!$  
! File: psb_dsprn.f90
!
! Subroutine: psb_dsprn
!    Reinit sparse matrix structure for psblas routines.
! 
! Parameters: 
!    a        - type(<psb_dspmat_type>).          The sparse matrix to be reinitiated.      
!    desc_a   - type(<psb_desc_type>).            The communication descriptor.
!    info     - integer.                          Eventually returns an error code.
!
Subroutine psb_dsprn(a, desc_a,info)

  use psb_descriptor_type
  use psb_spmat_type
  use psb_serial_mod
  use psb_const_mod
  use psb_error_mod
  Implicit None

  !....Parameters...
  Type(psb_desc_type), intent(in)      :: desc_a
  Type(psb_dspmat_type), intent(inout) :: a
  integer, intent(out)                 :: info

  !locals
  Integer             :: icontxt
  Integer             :: nprow,npcol,myrow,mycol,err,err_act
  logical, parameter  :: debug=.false.
  integer             :: int_err(5)
  real(kind(1.d0))    :: real_err(5)
  character(len=20)   :: name, ch_err

  info = 0
  err  = 0
  int_err(1)=0
  name = 'psb_dsprn'
  call psb_erractionsave(err_act)

  icontxt = desc_a%matrix_data(psb_ctxt_)
  call blacs_gridinfo(icontxt, nprow, npcol, myrow, mycol)
  if (debug) &
       &write(*,*) 'starting spalloc ',icontxt,nprow,npcol,myrow

  !     ....verify blacs grid correctness..
  if (npcol.ne.1) then
    info = 2030
    call psb_errpush(info,name)
    goto 9999
  endif

  if (debug) write(*,*) 'got through igamx2d '

  if (.not.psb_is_asb_dec(desc_a%matrix_data(psb_dec_type_))) then
    info=590     
    call psb_errpush(info,name)
    goto 9999
  endif

  select case(psb_sp_getifld(psb_state_,a,info))
  case(psb_spmat_asb_) 

    a%aspk(:) = dzero

    if (psb_sp_getifld(psb_upd_,a,info)==psb_upd_perm_) then 
      if(a%fida(1:3).eq.'JAD') then
        a%ia1(a%infoa(psb_upd_pnt_)+psb_nnz_) = 0
      else
        a%ia2(a%infoa(psb_upd_pnt_)+psb_nnz_) = 0
      endif
    endif
    a%infoa(psb_state_) = psb_spmat_upd_
  case(psb_spmat_bld_) 
    ! in this case do nothing. this allows sprn to be called 
    ! right after allocate, with spins doing the right thing.
    ! hopefully :-)

  case( psb_spmat_upd_) 

  case default
    info=591     
    call psb_errpush(info,name)
  end select

  if (info /= 0) goto 9999

  call psb_erractionrestore(err_act)
  return

9999 continue
  call psb_erractionrestore(err_act)
  if (err_act.eq.act_abort) then
     call psb_error(icontxt)
     return
  end if
  return

end subroutine psb_dsprn
