amg4psblas/mlprec/mld_z_as_smoother.f90

!!$
!!$ 
!!$                           MLD2P4  version 2.0
!!$  MultiLevel Domain Decomposition Parallel Preconditioners Package
!!$             based on PSBLAS (Parallel Sparse BLAS version 3.0)
!!$  
!!$  (C) Copyright 2008,2009,2010,2012
!!$
!!$                      Salvatore Filippone  University of Rome Tor Vergata
!!$                      Alfredo Buttari      CNRS-IRIT, Toulouse
!!$                      Pasqua D'Ambra       ICAR-CNR, Naples
!!$                      Daniela di Serafino  Second University of Naples
!!$ 
!!$  Redistribution and use in source and binary forms, with or without
!!$  modification, are permitted provided that the following conditions
!!$  are met:
!!$    1. Redistributions of source code must retain the above copyright
!!$       notice, this list of conditions and the following disclaimer.
!!$    2. Redistributions in binary form must reproduce the above copyright
!!$       notice, this list of conditions, and the following disclaimer in the
!!$       documentation and/or other materials provided with the distribution.
!!$    3. The name of the MLD2P4 group or the names of its contributors may
!!$       not be used to endorse or promote products derived from this
!!$       software without specific written permission.
!!$ 
!!$  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
!!$  ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
!!$  TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
!!$  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE MLD2P4 GROUP OR ITS CONTRIBUTORS
!!$  BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
!!$  CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
!!$  SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
!!$  INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
!!$  CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
!!$  ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
!!$  POSSIBILITY OF SUCH DAMAGE.
!!$ 
!!$
!
!
!
!
!
!
module mld_z_as_smoother

  use mld_z_base_smoother_mod
  
  type, extends(mld_z_base_smoother_type) :: mld_z_as_smoother_type
    ! The local solver component is inherited from the
    ! parent type. 
    !    class(mld_z_base_solver_type), allocatable :: sv
    !    
    type(psb_zspmat_type) :: nd
    type(psb_desc_type)   :: desc_data 
    integer               :: novr, restr, prol, nd_nnz_tot
  contains
    procedure, pass(sm) :: check   => mld_z_as_smoother_check
    procedure, pass(sm) :: dump    => mld_z_as_smoother_dmp
    procedure, pass(sm) :: build   => mld_z_as_smoother_bld
    procedure, pass(sm) :: apply_v => mld_z_as_smoother_apply_vect
    procedure, pass(sm) :: apply_a => mld_z_as_smoother_apply
    procedure, pass(sm) :: free    => mld_z_as_smoother_free
    procedure, pass(sm) :: seti    => mld_z_as_smoother_seti
    procedure, pass(sm) :: setc    => mld_z_as_smoother_setc
    procedure, pass(sm) :: setr    => mld_z_as_smoother_setr
    procedure, pass(sm) :: descr   => z_as_smoother_descr
    procedure, pass(sm) :: sizeof  => z_as_smoother_sizeof
    procedure, pass(sm) :: default => z_as_smoother_default
    procedure, pass(sm) :: get_nzeros => z_as_smoother_get_nzeros
  end type mld_z_as_smoother_type
  
  
  private :: z_as_smoother_descr,  z_as_smoother_sizeof, &
       &  z_as_smoother_default, z_as_smoother_get_nzeros

  character(len=6), parameter, private :: &
       &  restrict_names(0:4)=(/'none ','halo ','     ','     ','     '/)
  character(len=12), parameter, private :: &
       &  prolong_names(0:3)=(/'none       ','sum        ','average    ','square root'/)


  interface 
    subroutine mld_z_as_smoother_check(sm,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      class(mld_z_as_smoother_type), intent(inout) :: sm 
      integer, intent(out)                   :: info
    end subroutine mld_z_as_smoother_check
  end interface
  
  interface 
    subroutine mld_z_as_smoother_apply_vect(alpha,sm,x,beta,y,desc_data,trans,sweeps,work,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      type(psb_desc_type), intent(in)              :: desc_data
      class(mld_z_as_smoother_type), intent(inout) :: sm
      type(psb_z_vect_type),intent(inout)          :: x
      type(psb_z_vect_type),intent(inout)          :: y
      complex(psb_dpk_),intent(in)                    :: alpha,beta
      character(len=1),intent(in)                  :: trans
      integer, intent(in)                          :: sweeps
      complex(psb_dpk_),target, intent(inout)         :: work(:)
      integer, intent(out)                         :: info
    end subroutine mld_z_as_smoother_apply_vect
  end interface
  
  interface
    subroutine mld_z_as_smoother_apply(alpha,sm,x,beta,y,desc_data,trans,sweeps,work,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      type(psb_desc_type), intent(in)      :: desc_data
      class(mld_z_as_smoother_type), intent(in) :: sm
      complex(psb_dpk_),intent(inout)         :: x(:)
      complex(psb_dpk_),intent(inout)         :: y(:)
      complex(psb_dpk_),intent(in)            :: alpha,beta
      character(len=1),intent(in)          :: trans
      integer, intent(in)                  :: sweeps
      complex(psb_dpk_),target, intent(inout) :: work(:)
      integer, intent(out)                 :: info
    end subroutine mld_z_as_smoother_apply
  end interface
  
  interface
    subroutine mld_z_as_smoother_bld(a,desc_a,sm,upd,info,amold,vmold)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, &
           & psb_desc_type, psb_z_base_sparse_mat
      type(psb_zspmat_type), intent(in), target          :: a
      Type(psb_desc_type), Intent(in)                    :: desc_a 
      class(mld_z_as_smoother_type), intent(inout)       :: sm
      character, intent(in)                              :: upd
      integer, intent(out)                               :: info
      class(psb_z_base_sparse_mat), intent(in), optional :: amold
      class(psb_z_base_vect_type), intent(in), optional  :: vmold
    end subroutine mld_z_as_smoother_bld
  end interface
  
  interface 
    subroutine mld_z_as_smoother_seti(sm,what,val,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      class(mld_z_as_smoother_type), intent(inout) :: sm 
      integer, intent(in)                    :: what 
      integer, intent(in)                    :: val
      integer, intent(out)                   :: info
    end subroutine mld_z_as_smoother_seti
  end interface
  
  interface 
    subroutine mld_z_as_smoother_setc(sm,what,val,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      class(mld_z_as_smoother_type), intent(inout) :: sm
      integer, intent(in)                    :: what 
      character(len=*), intent(in)           :: val
      integer, intent(out)                   :: info
    end subroutine mld_z_as_smoother_setc
  end interface
  
  interface 
    subroutine mld_z_as_smoother_setr(sm,what,val,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      class(mld_z_as_smoother_type), intent(inout) :: sm 
      integer, intent(in)                    :: what 
      real(psb_dpk_), intent(in)             :: val
      integer, intent(out)                   :: info
    end subroutine mld_z_as_smoother_setr
  end interface
  
  interface 
    subroutine mld_z_as_smoother_free(sm,info)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      class(mld_z_as_smoother_type), intent(inout) :: sm
      integer, intent(out)                       :: info
    end subroutine mld_z_as_smoother_free
  end interface
  
  interface 
    subroutine mld_z_as_smoother_dmp(sm,ictxt,level,info,prefix,head,smoother,solver)
      import :: psb_zspmat_type, psb_z_vect_type, psb_z_base_vect_type, &
           & psb_dpk_, mld_z_as_smoother_type, psb_long_int_k_, psb_desc_type
      class(mld_z_as_smoother_type), intent(in) :: sm
      integer, intent(in)              :: ictxt,level
      integer, intent(out)             :: info
      character(len=*), intent(in), optional :: prefix, head
      logical, optional, intent(in)    :: smoother, solver
    end subroutine mld_z_as_smoother_dmp
  end interface
  
contains

  function z_as_smoother_sizeof(sm) result(val)
    implicit none 
    ! Arguments
    class(mld_z_as_smoother_type), intent(in) :: sm
    integer(psb_long_int_k_) :: val
    integer             :: i

    val = psb_sizeof_int 
    if (allocated(sm%sv)) val = val + sm%sv%sizeof()
    val = val + sm%nd%sizeof()

    return
  end function z_as_smoother_sizeof

  function z_as_smoother_get_nzeros(sm) result(val)
    implicit none 
    class(mld_z_as_smoother_type), intent(in) :: sm
    integer(psb_long_int_k_) :: val
    integer             :: i
    val = 0
    if (allocated(sm%sv)) &
         &  val =  sm%sv%get_nzeros()
    val = val + sm%nd%get_nzeros()

  end function z_as_smoother_get_nzeros

  subroutine z_as_smoother_default(sm)

    use psb_base_mod, only : psb_halo_, psb_none_

    Implicit None

    ! Arguments
    class(mld_z_as_smoother_type), intent(inout) :: sm 


    sm%restr = psb_halo_
    sm%prol  = psb_none_
    sm%novr  = 1


    if (allocated(sm%sv)) then 
      call sm%sv%default()
    end if

    return
  end subroutine z_as_smoother_default


  subroutine z_as_smoother_descr(sm,info,iout,coarse)

    Implicit None

    ! Arguments
    class(mld_z_as_smoother_type), intent(in) :: sm
    integer, intent(out)                      :: info
    integer, intent(in), optional             :: iout
    logical, intent(in), optional             :: coarse

    ! Local variables
    integer      :: err_act
    integer      :: ictxt, me, np
    character(len=20), parameter :: name='mld_z_as_smoother_descr'
    integer :: iout_
    logical      :: coarse_

    call psb_erractionsave(err_act)
    info = psb_success_
    if (present(coarse)) then 
      coarse_ = coarse
    else
      coarse_ = .false.
    end if
    if (present(iout)) then 
      iout_ = iout 
    else
      iout_ = 6
    endif

    if (.not.coarse_) then 
      write(iout_,*) '  Additive Schwarz with  ',&
           &  sm%novr, ' overlap layers.'
      write(iout_,*) '  Restrictor:  ',restrict_names(sm%restr)
      write(iout_,*) '  Prolongator: ',prolong_names(sm%prol)
      write(iout_,*) '  Local solver:'
    endif
    if (allocated(sm%sv)) then 
      call sm%sv%descr(info,iout_,coarse=coarse)
    end if

    call psb_erractionrestore(err_act)
    return

9999 continue
    call psb_erractionrestore(err_act)
    if (err_act == psb_act_abort_) then
      call psb_error()
      return
    end if
    return
  end subroutine z_as_smoother_descr

end module mld_z_as_smoother