mld2p4:

Make.inc.in
 config/ax_f90_module_extension.m4
 config/pac.m4
 configure.ac
 configure
 examples/fileread/Makefile
 examples/pdegen/Makefile
 mlprec/Makefile
 mlprec/impl/Makefile
 mlprec/impl/level/Makefile
 mlprec/impl/smoother/Makefile
 mlprec/impl/solver/Makefile
 tests/fileread/Makefile
 tests/newslv/Makefile
 tests/pdegen/Makefile

Changes from rpmtest branch. Should be working now.

config/ax_f90_module_extension.m4

@@ -0,0 +1,45 @@
+dnl @synopsis AX_F90_MODULE_EXTENSION
+dnl
+dnl Find Fortran 90 modules file extension. The module extension is
+dnl stored in the cached variable ax_f90_modext, or "unknown" if the
+dnl extension cannot be found.
+dnl
+dnl @category Fortran
+dnl @author Luc Maisonobe <luc@spaceroots.org>
+dnl @version 2005-06-17
+dnl @license AllPermissive
+dnl modified Salvatore Filippone <salvatore.filippone@uniroma2.it>
+dnl make it work even if ac_fc_ext="f"
+
+AC_DEFUN([AX_F90_MODULE_EXTENSION],[
+AC_CACHE_CHECK([fortran 90 modules extension],
+ax_cv_f90_modext,
+[AC_LANG_PUSH(Fortran)
+i=0
+while test \( -f tmpdir_$i \) -o \( -d tmpdir_$i \) ; do
+  i=`expr $i + 1`
+done
+mkdir tmpdir_$i
+cd tmpdir_$i
+AC_COMPILE_IFELSE([
+      module conftest_module
+       contains
+       subroutine conftest_routine
+       write(*,'(a)') 'gotcha!'
+       end subroutine conftest_routine
+      end module conftest_module
+  ],
+  [ax_cv_f90_modext=`ls | sed -n 's,conftest_module\.,,p'`
+   if test x$ax_cv_f90_modext = x ; then
+dnl Some F90 compilers put module filename in uppercase letters
+     ax_cv_f90_modext=`ls | sed -n 's,CONFTEST_MODULE\.,,p'`
+     if test x$ax_cv_f90_modext = x ; then
+       ax_cv_f90_modext=unknown
+     fi
+   fi
+  ],
+  [ax_cv_f90_modext=unknown])
+cd ..
+rm -fr tmpdir_$i
+AC_LANG_POP(Fortran)
+])])